﻿figure it out - a statistical consultancy from the Institute of Work Psychology, University of Sheffield

## Mplus code for mediation, moderation, and moderated mediation models

Model 76: 1 or more mediators, in parallel if multiple (example uses 1), 2 moderators, both moderating each of the IV-Mediator path, the Mediator-DV path and the direct IV-DV path

Example Variables: 1 predictor X, 1 mediator M, 2 moderators W, Z, 1 outcome Y

Preliminary notes:

The code below assumes that

• The primary IV (variable X) is continuous or dichotomous.
• Any moderators (variables W, V, Q, Z) are continuous, though the only adaptation required to handle dichotomous moderators is in the MODEL CONSTRAINT: and loop plot code - an example of how to do this is given in model 1b. Handling categorical moderators with > 2 categories is demonstrated in model 1d.
• Any mediators (variable M, or M1, M2, etc.) are continuous and satisfy the assumptions of standard multiple regression. An example of how to handle a dichotomous mediator is given in model 4c.
• The DV (variable Y) is continuous and satisfies the assumptions of standard multiple regression - an example of how to handle a dichotomous DV is given in model 1e (i.e. a moderated logistic regression) and in model 4d (i.e. an indirect effect in a logistic regression).

Model Diagram:

Statistical Diagram:

Model Equation(s):

Y = b0 + b1M + b2MW + b3MZ + c1'X + c2'W + c3'Z + c4'XW + c5'XZ
M = a0 + a1X + a2W + a3Z + a4XW + a5XZ

Algebra to calculate indirect and/or conditional effects by writing model as Y = a + bX:

Y = b0 + b1M + b2MW + b3MZ + c1'X + c2'W + c3'Z + c4'XW + c5'XZ
M = a0 + a1X + a2W + a3Z + a4XW + a5XZ

Hence... substituting in equation for M

Y = b0 + b1(a0 + a1X + a2W + a3Z + a4XW + a5XZ) + b2(a0 + a1X + a2W + a3Z + a4XW + a5XZ)W + b3(a0 + a1X + a2W + a3Z + a4XW + a5XZ)Z + c1'X + c2'W + c3'Z + c4'XW + c5'XZ

Hence... multiplying out brackets

Y = b0 + a0b1 + a1b1X + a2b1W + a3b1Z + a4b1XW + a5b1XZ + a0b2W + a1b2XW + a2b2WW + a3b2ZW + a4b2XWW + a5b2XZW + a0b3Z + a1b3XZ + a2b3WZ + a3b3ZZ + a4b3XWZ + a5b3XZZ + c1'X + c2'W + c3'Z + c4'XW + c5'XZ

Hence... grouping terms into form Y = a + bX

Y = (b0 + a0b1 + a2b1W + a3b1Z + a0b2W + a2b2WW + a3b2ZW + a0b3Z + a2b3WZ + a3b3ZZ + c2'W + c3'Z) + (a1b1 + a4b1W + a5b1Z + a1b2W + a4b2WW + a5b2ZW + a1b3Z + a4b3WZ + a5b3ZZ + c1' + c4'W + c5'Z)X

Hence...

One indirect effect(s) of X on Y, conditional on W, Z:

a1b1 + a4b1W + a5b1Z + a1b2W + a4b2WW + a5b2ZW + a1b3Z + a4b3WZ + a5b3ZZ = (a1 + a4W + a5Z)(b1 + b2W + b3Z)

One direct effect of X on Y, conditional on W, Z:

c1' + c4'W + c5'Z

Mplus code for the model:

! Predictor variable - X
! Mediator variable(s) – M
! Moderator variable(s) – W, Z
! Outcome variable - Y

USEVARIABLES = X M W Z Y XW XZ MW MZ;

! Create interaction terms
! Note that they have to be placed at end of USEVARIABLES subcommand above

DEFINE:
MW = M*W;
MZ = M*Z;
XW = X*W;
XZ = X*Z;

ANALYSIS:
TYPE = GENERAL;
ESTIMATOR = ML;
BOOTSTRAP = 10000;

! In model statement name each path and intercept using parentheses

MODEL:
[Y] (b0);
Y ON M (b1);
Y ON MW (b2);
Y ON MZ (b3);

Y ON X(cdash1);
Y ON W (cdash2);
Y ON Z (cdash3);
Y ON XW (cdash4);
Y ON XZ (cdash5);

[M] (a0);
M ON X (a1);
M ON W (a2);
M ON Z (a3);
M ON XW (a4);
M ON XZ (a5);

! Use model constraint subcommand to test conditional indirect effects
! You need to pick low, medium and high moderator values for W, Z
! for example, of 1 SD below mean, mean, 1 SD above mean

! 2 moderators, 3 values for each, gives 9 combinations
! arbitrary naming convention for conditional indirect and total effects used below:
! MEV_LOQ = medium value of V and low value of Q, etc.

MODEL CONSTRAINT:
NEW(LOW_W MED_W HIGH_W LOW_Z MED_Z HIGH_Z
ILOW_LOZ IMEW_LOZ IHIW_LOZ ILOW_MEZ IMEW_MEZ IHIW_MEZ
ILOW_HIZ IMEW_HIZ IHIW_HIZ
DLOW_LOZ DMEW_LOZ DHIW_LOZ DLOW_MEZ DMEW_MEZ DHIW_MEZ
DLOW_HIZ DMEW_HIZ DHIW_HIZ
TLOW_LOZ TMEW_LOZ THIW_LOZ TLOW_MEZ TMEW_MEZ THIW_MEZ
TLOW_HIZ TMEW_HIZ THIW_HIZ);

LOW_W = #LOWW;   ! replace #LOWW in the code with your chosen low value of W
MED_W = #MEDW;   ! replace #MEDW in the code with your chosen medium value of W
HIGH_W = #HIGHW;   ! replace #HIGHW in the code with your chosen high value of W

LOW_Z = #LOWZ;   ! replace #LOWZ in the code with your chosen low value of Z
MED_Z = #MEDZ;   ! replace #MEDZ in the code with your chosen medium value of Z
HIGH_Z = #HIGHZ;   ! replace #HIGHZ in the code with your chosen high value of Z

! Calc conditional indirect effects for each combination of moderator values

ILOW_LOZ = a1*b1 + a4*b1*LOW_W + a5*b1*LOW_Z + a1*b2*LOW_W +
a4*b2*LOW_W*LOW_W + a5*b2*LOW_Z*LOW_W + a1*b3*LOW_Z +
a4*b3*LOW_W*LOW_Z + a5*b3*LOW_Z*LOW_Z;
IMEW_LOZ = a1*b1 + a4*b1*MED_W + a5*b1*LOW_Z + a1*b2*MED_W +
a4*b2*MED_W*MED_W + a5*b2*LOW_Z*MED_W + a1*b3*LOW_Z +
a4*b3*MED_W*LOW_Z + a5*b3*LOW_Z*LOW_Z;
IHIW_LOZ = a1*b1 + a4*b1*HIGH_W + a5*b1*LOW_Z + a1*b2*HIGH_W +
a4*b2*HIGH_W*HIGH_W + a5*b2*LOW_Z*HIGH_W + a1*b3*LOW_Z +
a4*b3*HIGH_W*LOW_Z + a5*b3*LOW_Z*LOW_Z;

ILOW_MEZ = a1*b1 + a4*b1*LOW_W + a5*b1*MED_Z + a1*b2*LOW_W +
a4*b2*LOW_W*LOW_W + a5*b2*MED_Z*LOW_W + a1*b3*MED_Z +
a4*b3*LOW_W*MED_Z + a5*b3*MED_Z*MED_Z;
IMEW_MEZ = a1*b1 + a4*b1*MED_W + a5*b1*MED_Z + a1*b2*MED_W +
a4*b2*MED_W*MED_W + a5*b2*MED_Z*MED_W + a1*b3*MED_Z +
a4*b3*MED_W*MED_Z + a5*b3*MED_Z*MED_Z;
IHIW_MEZ = a1*b1 + a4*b1*HIGH_W + a5*b1*MED_Z + a1*b2*HIGH_W +
a4*b2*HIGH_W*HIGH_W + a5*b2*MED_Z*HIGH_W + a1*b3*MED_Z +
a4*b3*HIGH_W*MED_Z + a5*b3*MED_Z*MED_Z;

ILOW_HIZ = a1*b1 + a4*b1*LOW_W + a5*b1*HIGH_Z + a1*b2*LOW_W +
a4*b2*LOW_W*LOW_W + a5*b2*HIGH_Z*LOW_W + a1*b3*HIGH_Z +
a4*b3*LOW_W*HIGH_Z + a5*b3*HIGH_Z*HIGH_Z;
IMEW_HIZ = a1*b1 + a4*b1*MED_W + a5*b1*HIGH_Z + a1*b2*MED_W +
a4*b2*MED_W*MED_W + a5*b2*HIGH_Z*MED_W + a1*b3*HIGH_Z +
a4*b3*MED_W*HIGH_Z + a5*b3*HIGH_Z*HIGH_Z;
IHIW_HIZ = a1*b1 + a4*b1*HIGH_W + a5*b1*HIGH_Z + a1*b2*HIGH_W +
a4*b2*HIGH_W*HIGH_W + a5*b2*HIGH_Z*HIGH_W + a1*b3*HIGH_Z +
a4*b3*HIGH_W*HIGH_Z + a5*b3*HIGH_Z*HIGH_Z;

! Calc conditional direct effects for each combination of moderator values

DLOW_LOZ = cdash1 + cdash4*LOW_W + cdash5*LOW_Z;
DMEW_LOZ = cdash1 + cdash4*MED_W + cdash5*LOW_Z;
DHIW_LOZ = cdash1 + cdash4*HIGH_W + cdash5*LOW_Z;

DLOW_MEZ = cdash1 + cdash4*LOW_W + cdash5*MED_Z;
DMEW_MEZ = cdash1 + cdash4*MED_W + cdash5*MED_Z;
DHIW_MEZ = cdash1 + cdash4*HIGH_W + cdash5*MED_Z;

DLOW_HIZ = cdash1 + cdash4*LOW_W + cdash5*HIGH_Z;
DMEW_HIZ = cdash1 + cdash4*MED_W + cdash5*HIGH_Z;
DHIW_HIZ = cdash1 + cdash4*HIGH_W + cdash5*HIGH_Z;

! Calc conditional total effects for each combination of moderator values

TLOW_LOZ = ILOW_LOZ + DLOW_LOZ;
TMEW_LOZ = IMEW_LOZ + DMEW_LOZ;
THIW_LOZ = IHIW_LOZ + DHIW_LOZ;

TLOW_MEZ = ILOW_MEZ + DLOW_MEZ;
TMEW_MEZ = IMEW_MEZ + DMEW_MEZ;
THIW_MEZ = IHIW_MEZ + DHIW_MEZ;

TLOW_HIZ = ILOW_HIZ + DLOW_HIZ;
TMEW_HIZ = IMEW_HIZ + DMEW_HIZ;
THIW_HIZ = IHIW_HIZ + DHIW_HIZ;

! Use loop plot to plot conditional indirect effect of X on Y for each combination of low, med, high moderator values
! Could be edited to show conditional direct or conditional total effects instead
! NOTE - values of 1,5 in LOOP() statement need to be replaced by
! logical min and max limits of predictor X used in analysis

PLOT(PLOW_LOZ PMEW_LOZ PHIW_LOZ PLOW_MEZ PMEW_MEZ PHIW_MEZ
PLOW_HIZ PMEW_HIZ PHIW_HIZ);

LOOP(XVAL,1,5,0.1);

PLOW_LOZ = ILOW_LOZ*XVAL;
PMEW_LOZ = IMEW_LOZ*XVAL;
PHIW_LOZ = IHIW_LOZ*XVAL;

PLOW_MEZ = ILOW_MEZ*XVAL;
PMEW_MEZ = IMEW_MEZ*XVAL;
PHIW_MEZ = IHIW_MEZ*XVAL;

PLOW_HIZ = ILOW_HIZ*XVAL;
PMEW_HIZ = IMEW_HIZ*XVAL;
PHIW_HIZ = IHIW_HIZ*XVAL;

PLOT:
TYPE = plot2;

OUTPUT:
STAND CINT(bcbootstrap);

Return to Model Template index.

To cite this page and/or any code used, please use:
Stride C.B., Gardner S., Catley. N. & Thomas, F.(2015) 'Mplus code for the mediation, moderation, and moderated mediation model templates from Andrew Hayes' PROCESS analysis examples' , http://www.figureitout.org.uk

 Home Statistical Consultancy Data Management Public Training Courses Inhouse & Bespoke Training Links & Resources About Us & Contact Details