Preliminary notes:

The code below assumes that

• The latent IV (factor X) is measured by continuous observed variables X1-X4.
• Any latent moderator(s) (factors W, V, Q, Z) are measured by continuous observed variables W1-W4, Z1-Z4, V1-V4, Q1-Q4 respectively.
• Any latent mediator(s) (factor M, or factors M1, M2, etc.) are measured by continuous observed variables M1-M4 or M1_1-M1-4, M2_1-M2_4 respectively.
• The latent outcome Y is measured by continuous observed variables Y1-Y4.

Model Diagram (factor indicator variables omitted for space/clarity reasons):

Statistical Diagram (factor indicator variables omitted for space/clarity reasons):

Model Equation(s):

Y = b0 + b1M + b2MW + b3MZ + b4MWZ + c1'X + c2W + c3'Z + c4'XW + c5'XZ + c6'WZ + c7'XWZ
M = a0 + a1X + a2W + a3Z + a4XW + a5XZ + a6WZ + a7XWZ

Algebra to calculate indirect and/or conditional effects by writing model as Y = a + bX:

Y = b0 + b1M + b2MW + b3MZ + b4MWZ + c1'X + c2W + c3'Z + c4'XW + c5'XZ + c6'WZ + c7'XWZ
M = a0 + a1X + a2W + a3Z + a4XW + a5XZ + a6WZ + a7XWZ

Hence... substituting in equation for M

Y = b0 + b1(a0 + a1X + a2W + a3Z + a4XW + a5XZ + a6WZ + a7XWZ) + b2(a0 + a1X + a2W + a3Z + a4XW + a5XZ + a6WZ + a7XWZ)W + b3(a0 + a1X + a2W + a3Z + a4XW + a5XZ + a6WZ + a7XWZ)Z + b4(a0 + a1X + a2W + a3Z + a4XW + a5XZ + a6WZ + a7XWZ)WZ + c1'X + c2W + c3'Z + c4'XW + c5'XZ + c6'WZ + c7'XWZ

Hence... multiplying out brackets

Y = b0 + a0b1 + a1b1X + a2b1W + a3b1Z + a4b1XW + a5b1XZ + a6b1WZ + a7b1XWZ + a0b2W + a1b2XW + a2b2WW + a3b2ZW + a4b2XWW + a5b2XZW + a6b2WWZ + a7b2XWWZ + a0b3Z + a1b3XZ + a2b3WZ + a3b3ZZ + a4b3XWZ + a5b3XZZ + a6b3WZZ + a7b3XWZZ + a0b4WZ + a1b4XWZ + a2b4WWZ + a3b4WZZ + a4b4XWWZ + a5b4XWZZ + a6b4WWZZ + a7b4XWWZZ + c1'X + c2W + c3'Z + c4'XW + c5'XZ + c6'WZ + c7'XWZ

Hence... grouping terms into form Y = a + bX

Y = (b0 + a0b1 + a2b1W + a3b1Z + a6b1WZ + a0b2W + a2b2WW + a3b2ZW + a6b2WWZ + a0b3Z + a2b3WZ + a3b3ZZ + a6b3WZZ + a0b4WZ + a2b4WWZ + a3b4WZZ + a6b4WWZZ+ c2W + c3'Z + c6'WZ) + (a1b1 + a4b1W + a5b1Z + a7b1WZ + a1b2W + a4b2WW + a5b2ZW + a7b2WWZ + a1b3Z + a4b3WZ + a5b3ZZ + a7b3WZZ + a1b4WZ + a4b4WWZ + a5b4WZZ + a7b4WWZZ + c1' + c4'W + c5'Z + c7'WZ)X

Hence...

One indirect effect(s) of X on Y, conditional on W, Z:

a1b1 + a4b1W + a5b1Z + a7b1WZ + a1b2W + a4b2WW + a5b2ZW + a7b2WWZ + a1b3Z + a4b3WZ + a5b3ZZ + a7b3WZZ + a1b4WZ + a4b4WWZ + a5b4WZZ + a7b4WWZZ = (a1 + a4W + a5Z + a7WZ)(b1 + b2W + b3Z + b4WZ)

One direct effect of X on Y, conditional on W, Z:

c1' + c4'W + c5'Z + c7'WZ

Mplus code for the model:

! Latent predictor variable X measured by X1-X4
! Latent mediator M measured by 4 observed variables M1-M4
! Latent moderators W and Z, each measured by sets of 4 observed variables W1-W4 and Z1-Z4 respectively
! Latent outcome variable Y measured by Y1-Y4

USEVARIABLES = X1 X2 X3 X4 M1 M2 M3 M4
W1 W2 W3 W4 Z1 Z2 Z3 Z4
Y1 Y2 Y3 Y4;

ANALYSIS:
   TYPE = GENERAL RANDOM;
   ESTIMATOR = ML;
   ALGORITHM = INTEGRATION;

! In model statement first state measurement model
! Then create any latent interactions required
! Then state structural model naming each path and intercept using parentheses

MODEL:

! Measurement model
! Identify moderator factors by fixing variance = 1 (instead of first loading)
! This makes these factors standardised
   X BY X1 X2 X3 X4;
   M BY M1 M2 M3 M4;
   W BY W1* W2 W3 W4;
   Z BY Z1* Z2 Z3 Z4;
   Y BY Y1 Y2 Y3 Y4;

    W@1;   Z@1;

! Create latent interactions
   MW | M XWITH W;
   MZ | M XWITH Z;
   XW | X XWITH W;
   XZ | X XWITH Z;
   WZ | W XWITH Z;
   MWZ | M XWITH WZ;
   XWZ | X XWITH WZ;

! Fit structural model and name parameters
! Note that intercepts of M, Y are fixed = 0 since they are latent vars
! so no code to state and name them as parameters
   Y ON M (b1);
   Y ON MW (b2);
   Y ON MZ (b3);
   Y ON MWZ (b4);

   Y ON X(cdash1);
   Y ON W (cdash2);
   Y ON Z (cdash3);
   Y ON XW (cdash4);
   Y ON XZ (cdash5);
   Y ON WZ (cdash6);
   Y ON XWZ (cdash7);

   M ON X (a1);
   M ON W (a2);
   M ON Z (a3);
   M ON XW (a4);
   M ON XZ (a5);
   M ON WZ (a6);
   M ON XWZ (a7);

! Use model constraint subcommand to test conditional indirect effects
! You need to pick low, medium and high moderator values for W, Z
! for example, of 1 SD below mean, mean, 1 SD above mean

! 2 moderators, 3 values for each, gives 9 combinations
! arbitrary naming convention for conditional indirect and total effects used below:
! MEV_LOQ = medium value of V and low value of Q, etc.

MODEL CONSTRAINT:
    NEW(LOW_W MED_W HIGH_W LOW_Z MED_Z HIGH_Z
    ILOW_LOZ IMEW_LOZ IHIW_LOZ ILOW_MEZ IMEW_MEZ IHIW_MEZ
    ILOW_HIZ IMEW_HIZ IHIW_HIZ
    DLOW_LOZ DMEW_LOZ DHIW_LOZ DLOW_MEZ DMEW_MEZ DHIW_MEZ
    DLOW_HIZ DMEW_HIZ DHIW_HIZ
    TLOW_LOZ TMEW_LOZ THIW_LOZ TLOW_MEZ TMEW_MEZ THIW_MEZ
    TLOW_HIZ TMEW_HIZ THIW_HIZ);

    LOW_W = -1;   ! -1 SD below mean value of W
    MED_W = 0;   ! mean value of W
    HIGH_W = 1;   ! +1 SD above mean value of W

    LOW_Z = -1;   ! -1 SD below mean value of Z
    MED_Z = 0;   ! mean value of Z
    HIGH_Z = 1;   ! +1 SD above mean value of Z

! Calc conditional indirect effects for each combination of moderator values

    ILOW_LOZ = a1*b1 + a4*b1*LOW_W + a5*b1*LOW_Z + a7*b1*LOW_W*LOW_Z +
     a1*b2*LOW_W + a4*b2*LOW_W*LOW_W + a5*b2*LOW_Z*LOW_W +
     a7*b2*LOW_W*LOW_W*LOW_Z + a1*b3*LOW_Z + a4*b3*LOW_W*LOW_Z +
     a5*b3*LOW_Z*LOW_Z + a7*b3*LOW_W*LOW_Z*LOW_Z + a1*b4*LOW_W*LOW_Z +
     a4*b4*LOW_W*LOW_W*LOW_Z + a5*b4*LOW_W*LOW_Z*LOW_Z +
     a7*b4*LOW_W*LOW_W*LOW_Z*LOW_Z;
    IMEW_LOZ = a1*b1 + a4*b1*MED_W + a5*b1*LOW_Z + a7*b1*MED_W*LOW_Z +
     a1*b2*MED_W + a4*b2*MED_W*MED_W + a5*b2*LOW_Z*MED_W +
     a7*b2*MED_W*MED_W*LOW_Z + a1*b3*LOW_Z + a4*b3*MED_W*LOW_Z +
     a5*b3*LOW_Z*LOW_Z + a7*b3*MED_W*LOW_Z*LOW_Z + a1*b4*MED_W*LOW_Z +
     a4*b4*MED_W*MED_W*LOW_Z + a5*b4*MED_W*LOW_Z*LOW_Z +
     a7*b4*MED_W*MED_W*LOW_Z*LOW_Z;
    IHIW_LOZ = a1*b1 + a4*b1*HIGH_W + a5*b1*LOW_Z + a7*b1*HIGH_W*LOW_Z +
     a1*b2*HIGH_W + a4*b2*HIGH_W*HIGH_W + a5*b2*LOW_Z*HIGH_W +
     a7*b2*HIGH_W*HIGH_W*LOW_Z + a1*b3*LOW_Z + a4*b3*HIGH_W*LOW_Z +
     a5*b3*LOW_Z*LOW_Z + a7*b3*HIGH_W*LOW_Z*LOW_Z + a1*b4*HIGH_W*LOW_Z +
     a4*b4*HIGH_W*HIGH_W*LOW_Z + a5*b4*HIGH_W*LOW_Z*LOW_Z +
     a7*b4*HIGH_W*HIGH_W*LOW_Z*LOW_Z;

    ILOW_MEZ = a1*b1 + a4*b1*LOW_W + a5*b1*MED_Z + a7*b1*LOW_W*MED_Z +
     a1*b2*LOW_W + a4*b2*LOW_W*LOW_W + a5*b2*MED_Z*LOW_W +
     a7*b2*LOW_W*LOW_W*MED_Z + a1*b3*MED_Z + a4*b3*LOW_W*MED_Z +
     a5*b3*MED_Z*MED_Z + a7*b3*LOW_W*MED_Z*MED_Z + a1*b4*LOW_W*MED_Z +
     a4*b4*LOW_W*LOW_W*MED_Z + a5*b4*LOW_W*MED_Z*MED_Z +
     a7*b4*LOW_W*LOW_W*MED_Z*MED_Z;
    IMEW_MEZ = a1*b1 + a4*b1*MED_W + a5*b1*MED_Z + a7*b1*MED_W*MED_Z +
     a1*b2*MED_W + a4*b2*MED_W*MED_W + a5*b2*MED_Z*MED_W +
     a7*b2*MED_W*MED_W*MED_Z + a1*b3*MED_Z + a4*b3*MED_W*MED_Z +
     a5*b3*MED_Z*MED_Z + a7*b3*MED_W*MED_Z*MED_Z + a1*b4*MED_W*MED_Z +
     a4*b4*MED_W*MED_W*MED_Z + a5*b4*MED_W*MED_Z*MED_Z +
     a7*b4*MED_W*MED_W*MED_Z*MED_Z;
    IHIW_MEZ = a1*b1 + a4*b1*HIGH_W + a5*b1*MED_Z + a7*b1*HIGH_W*MED_Z +
     a1*b2*HIGH_W + a4*b2*HIGH_W*HIGH_W + a5*b2*MED_Z*HIGH_W +
     a7*b2*HIGH_W*HIGH_W*MED_Z + a1*b3*MED_Z + a4*b3*HIGH_W*MED_Z +
     a5*b3*MED_Z*MED_Z + a7*b3*HIGH_W*MED_Z*MED_Z + a1*b4*HIGH_W*MED_Z +
     a4*b4*HIGH_W*HIGH_W*MED_Z + a5*b4*HIGH_W*MED_Z*MED_Z +
     a7*b4*HIGH_W*HIGH_W*MED_Z*MED_Z;

    ILOW_HIZ = a1*b1 + a4*b1*LOW_W + a5*b1*HIGH_Z + a7*b1*LOW_W*HIGH_Z +
     a1*b2*LOW_W + a4*b2*LOW_W*LOW_W + a5*b2*HIGH_Z*LOW_W +
     a7*b2*LOW_W*LOW_W*HIGH_Z + a1*b3*HIGH_Z + a4*b3*LOW_W*HIGH_Z +
     a5*b3*HIGH_Z*HIGH_Z + a7*b3*LOW_W*HIGH_Z*HIGH_Z + a1*b4*LOW_W*HIGH_Z +
     a4*b4*LOW_W*LOW_W*HIGH_Z + a5*b4*LOW_W*HIGH_Z*HIGH_Z +
     a7*b4*LOW_W*LOW_W*HIGH_Z*HIGH_Z;
    IMEW_HIZ = a1*b1 + a4*b1*MED_W + a5*b1*HIGH_Z + a7*b1*MED_W*HIGH_Z +
     a1*b2*MED_W + a4*b2*MED_W*MED_W + a5*b2*HIGH_Z*MED_W +
     a7*b2*MED_W*MED_W*HIGH_Z + a1*b3*HIGH_Z + a4*b3*MED_W*HIGH_Z +
     a5*b3*HIGH_Z*HIGH_Z + a7*b3*MED_W*HIGH_Z*HIGH_Z + a1*b4*MED_W*HIGH_Z +
     a4*b4*MED_W*MED_W*HIGH_Z + a5*b4*MED_W*HIGH_Z*HIGH_Z +
     a7*b4*MED_W*MED_W*HIGH_Z*HIGH_Z;
    IHIW_HIZ = a1*b1 + a4*b1*HIGH_W + a5*b1*HIGH_Z + a7*b1*HIGH_W*HIGH_Z +
     a1*b2*HIGH_W + a4*b2*HIGH_W*HIGH_W + a5*b2*HIGH_Z*HIGH_W +
     a7*b2*HIGH_W*HIGH_W*HIGH_Z + a1*b3*HIGH_Z + a4*b3*HIGH_W*HIGH_Z +
     a5*b3*HIGH_Z*HIGH_Z + a7*b3*HIGH_W*HIGH_Z*HIGH_Z + a1*b4*HIGH_W*HIGH_Z +
     a4*b4*HIGH_W*HIGH_W*HIGH_Z + a5*b4*HIGH_W*HIGH_Z*HIGH_Z +
     a7*b4*HIGH_W*HIGH_W*HIGH_Z*HIGH_Z;

! Calc conditional direct effects for each combination of moderator values

    DLOW_LOZ = cdash1 + cdash4*LOW_W + cdash5*LOW_Z + cdash7*LOW_W*LOW_Z;
    DMEW_LOZ = cdash1 + cdash4*MED_W + cdash5*LOW_Z + cdash7*MED_W*LOW_Z;
    DHIW_LOZ = cdash1 + cdash4*HIGH_W + cdash5*LOW_Z + cdash7*HIGH_W*LOW_Z;

    DLOW_MEZ = cdash1 + cdash4*LOW_W + cdash5*MED_Z + cdash7*LOW_W*MED_Z;
    DMEW_MEZ = cdash1 + cdash4*MED_W + cdash5*MED_Z + cdash7*MED_W*MED_Z;
    DHIW_MEZ = cdash1 + cdash4*HIGH_W + cdash5*MED_Z + cdash7*HIGH_W*MED_Z;

    DLOW_HIZ = cdash1 + cdash4*LOW_W + cdash5*HIGH_Z + cdash7*LOW_W*HIGH_Z;
    DMEW_HIZ = cdash1 + cdash4*MED_W + cdash5*HIGH_Z + cdash7*MED_W*HIGH_Z;
    DHIW_HIZ = cdash1 + cdash4*HIGH_W + cdash5*HIGH_Z + cdash7*HIGH_W*HIGH_Z;

! Calc conditional total effects for each combination of moderator values

    TLOW_LOZ = ILOW_LOZ + DLOW_LOZ;
    TMEW_LOZ = IMEW_LOZ + DMEW_LOZ;
    THIW_LOZ = IHIW_LOZ + DHIW_LOZ;

    TLOW_MEZ = ILOW_MEZ + DLOW_MEZ;
    TMEW_MEZ = IMEW_MEZ + DMEW_MEZ;
    THIW_MEZ = IHIW_MEZ + DHIW_MEZ;

    TLOW_HIZ = ILOW_HIZ + DLOW_HIZ;
    TMEW_HIZ = IMEW_HIZ + DMEW_HIZ;
    THIW_HIZ = IHIW_HIZ + DHIW_HIZ;

! Use loop plot to plot conditional indirect effect of X on Y for each combination of low, med, high moderator values
! Could be edited to show conditional direct or conditional total effects instead
! NOTE - values from -3 to 3 in LOOP() statement since
! X is factor with mean set at default of 0

    PLOT(PLOW_LOZ PMEW_LOZ PHIW_LOZ PLOW_MEZ PMEW_MEZ PHIW_MEZ
    PLOW_HIZ PMEW_HIZ PHIW_HIZ);

    LOOP(XVAL,-3,3,0.1);

    PLOW_LOZ = ILOW_LOZ*XVAL;
    PMEW_LOZ = IMEW_LOZ*XVAL;
    PHIW_LOZ = IHIW_LOZ*XVAL;

    PLOW_MEZ = ILOW_MEZ*XVAL;
    PMEW_MEZ = IMEW_MEZ*XVAL;
    PHIW_MEZ = IHIW_MEZ*XVAL;

    PLOW_HIZ = ILOW_HIZ*XVAL;
    PMEW_HIZ = IMEW_HIZ*XVAL;
    PHIW_HIZ = IHIW_HIZ*XVAL;

PLOT:
   TYPE = plot2;

OUTPUT:
   CINT;

Return to Model Template index.

To cite this page and/or any code used, please use:
Stride C.B., Gardner S., Catley. N. & Thomas, F.(2015) 'Mplus code for the mediation, moderation, and moderated mediation model templates from Andrew Hayes' PROCESS analysis examples' , http://www.figureitout.org.uk