Preliminary notes:

The code below assumes that

• The primary IV (variable X) is continuous or dichotomous.
• Any moderators (variables W, V, Q, Z) are continuous, though the only adaptation required to handle dichotomous moderators is in the MODEL CONSTRAINT: and loop plot code - an example of how to do this is given in model 1b. Handling categorical moderators with > 2 categories is demonstrated in model 1d.
• Any mediators (variable M, or M1, M2, etc.) are continuous and satisfy the assumptions of standard multiple regression. An example of how to handle a dichotomous mediator is given in model 4c.
• The DV (variable Y) is continuous and satisfies the assumptions of standard multiple regression - an example of how to handle a dichotomous DV is given in model 1e (i.e. a moderated logistic regression) and in model 4d (i.e. an indirect effect in a logistic regression).

Model Diagram:

Statistical Diagram:

Model Equation(s):

Y = b0 + b1M + b2W + b3MW + b4MV + c1'X + c2'V + c3'XV
M = a0 + a1X + a2W + a3XW

Algebra to calculate indirect and/or conditional effects by writing model as Y = a + bX:

Y = b0 + b1M + b2W + b3MW + b4MV + c1'X + c2'V + c3'XV
M = a0 + a1X + a2W + a3XW

Hence... substituting in equation for M

Y = b0 + b1(a0 + a1X + a2W + a3XW) + b2W + b3(a0 + a1X + a2W + a3XW)W + b4(a0 + a1X + a2W + a3XW)V + c1'X + c2'V + c3'XV

Hence... multiplying out brackets

Y = b0 + a0b1 + a1b1X + a2b1W + a3b1XW + b2W + a0b3W + a1b3XW + a2b3WW + a3b3XWW + a0b4V + a1b4XV + a2b4WV + a3b4XWV + c1'X + c2'V + c3'XV

Hence... grouping terms into form Y = a + bX

Y = (b0 + a0b1 + a2b1W + b2W + a0b3W + a2b3WW + a0b4V + a2b4WV + c2'V) + (a1b1 + a3b1W + a1b3W + a3b3WW + a1b4V + a3b4WV + c1' + c3'V)X

Hence...

One indirect effect(s) of X on Y, conditional on W, V:

a1b1 + a3b1W + a1b3W + a3b3WW + a1b4V + a3b4WV = (a1 + a3W)(b1 + b3W + b4V)

One direct effect of X on Y, conditional on V:

c1' + c3'V

Mplus code for the model:

! Predictor variable - X
! Mediator variable(s) – M
! Moderator variable(s) – W, V
! Outcome variable - Y

USEVARIABLES = X M W V Y XW XV MW MV;

! Create interaction terms
! Note that they have to be placed at end of USEVARIABLES subcommand above

DEFINE:
   MW = M*W;
   MV = M*V;
   XW = X*W;
   XV = X*V;

ANALYSIS:
   TYPE = GENERAL;
   ESTIMATOR = ML;
   BOOTSTRAP = 10000;

! In model statement name each path and intercept using parentheses

MODEL:
   [Y] (b0);
   Y ON M (b1);
   Y ON W (b2);
   Y ON MW (b3);
   Y ON MV (b4);

   Y ON X (cdash1);
   Y ON V (cdash2);
   Y ON XV (cdash3);

   [M] (a0);
   M ON X (a1);
   M ON W (a2);
   M ON XW (a3);

! Use model constraint subcommand to test conditional indirect effects
! You need to pick low, medium and high moderator values for W, V
! for example, of 1 SD below mean, mean, 1 SD above mean

! 2 moderators, 3 values for each, gives 9 combinations
! arbitrary naming convention for conditional indirect and total effects used below:
! MEV_LOQ = medium value of V and low value of Q, etc.

MODEL CONSTRAINT:
    NEW(LOW_W MED_W HIGH_W LOW_V MED_V HIGH_V
    ILOW_LOV IMEW_LOV IHIW_LOV ILOW_MEV IMEW_MEV IHIW_MEV
    ILOW_HIV IMEW_HIV IHIW_HIV
    DIR_LOWV DIR_MEDV DIR_HIV
    TLOW_LOV TMEW_LOV THIW_LOV TLOW_MEV TMEW_MEV THIW_MEV
    TLOW_HIV TMEW_HIV THIW_HIV);

    LOW_W = #LOWW;   ! replace #LOWW in the code with your chosen low value of W
    MED_W = #MEDW;   ! replace #MEDW in the code with your chosen medium value of W
    HIGH_W = #HIGHW;   ! replace #HIGHW in the code with your chosen high value of W

    LOW_V = #LOWV;   ! replace #LOWV in the code with your chosen low value of V
    MED_V = #MEDV;   ! replace #MEDV in the code with your chosen medium value of V
    HIGH_V = #HIGHV;   ! replace #HIGHV in the code with your chosen high value of V

! Calc conditional indirect effects for each combination of moderator values

    ILOW_LOV = a1*b1 + a3*b1*LOW_W + a1*b3*LOW_W + a3*b3*LOW_W*LOW_W +
     a1*b4*LOW_V + a3*b4*LOW_W*LOW_V;
    IMEW_LOV = a1*b1 + a3*b1*MED_W + a1*b3*MED_W + a3*b3*MED_W*MED_W +
     a1*b4*LOW_V + a3*b4*MED_W*LOW_V;
    IHIW_LOV = a1*b1 + a3*b1*HIGH_W + a1*b3*HIGH_W + a3*b3*HIGH_W*HIGH_W +
     a1*b4*LOW_V + a3*b4*HIGH_W*LOW_V;

    ILOW_MEV = a1*b1 + a3*b1*LOW_W + a1*b3*LOW_W + a3*b3*LOW_W*LOW_W +
     a1*b4*MED_V + a3*b4*LOW_W*MED_V;
    IMEW_MEV = a1*b1 + a3*b1*MED_W + a1*b3*MED_W + a3*b3*MED_W*MED_W +
     a1*b4*MED_V + a3*b4*MED_W*MED_V;
    IHIW_MEV = a1*b1 + a3*b1*HIGH_W + a1*b3*HIGH_W + a3*b3*HIGH_W*HIGH_W +
     a1*b4*MED_V + a3*b4*HIGH_W*MED_V;

    ILOW_HIV = a1*b1 + a3*b1*LOW_W + a1*b3*LOW_W + a3*b3*LOW_W*LOW_W +
     a1*b4*HIGH_V + a3*b4*LOW_W*HIGH_V;
    IMEW_HIV = a1*b1 + a3*b1*MED_W + a1*b3*MED_W + a3*b3*MED_W*MED_W +
     a1*b4*HIGH_V + a3*b4*MED_W*HIGH_V;
    IHIW_HIV = a1*b1 + a3*b1*HIGH_W + a1*b3*HIGH_W + a3*b3*HIGH_W*HIGH_W +
     a1*b4*HIGH_V + a3*b4*HIGH_W*HIGH_V;

! Calc conditional direct effects for each combination of moderator values

    DIR_LOWV = cdash1 + cdash3*LOW_V;
    DIR_MEDV = cdash1 + cdash3*MED_V;
    DIR_HIV = cdash1 + cdash3*HIGH_V;

! Calc conditional total effects for each combination of moderator values

    TLOW_LOV = ILOW_LOV + DIR_LOWV;
    TMEW_LOV = IMEW_LOV + DIR_LOWV;
    THIW_LOV = IHIW_LOV + DIR_LOWV;

    TLOW_MEV = ILOW_MEV + DIR_MEDV;
    TMEW_MEV = IMEW_MEV + DIR_MEDV;
    THIW_MEV = IHIW_MEV + DIR_MEDV;

    TLOW_HIV = ILOW_HIV + DIR_HIV;
    TMEW_HIV = IMEW_HIV + DIR_HIV;
    THIW_HIV = IHIW_HIV + DIR_HIV;

! Use loop plot to plot conditional indirect effect of X on Y for each combination of low, med, high moderator values
! Could be edited to show conditional direct or conditional total effects instead
! NOTE - values of 1,5 in LOOP() statement need to be replaced by
! logical min and max limits of predictor X used in analysis

    PLOT(PLOW_LOV PMEW_LOV PHIW_LOV PLOW_MEV PMEW_MEV PHIW_MEV
    PLOW_HIV PMEW_HIV PHIW_HIV);

    LOOP(XVAL,1,5,0.1);

    PLOW_LOV = ILOW_LOV*XVAL;
    PMEW_LOV = IMEW_LOV*XVAL;
    PHIW_LOV = IHIW_LOV*XVAL;

    PLOW_MEV = ILOW_MEV*XVAL;
    PMEW_MEV = IMEW_MEV*XVAL;
    PHIW_MEV = IHIW_MEV*XVAL;

    PLOW_HIV = ILOW_HIV*XVAL;
    PMEW_HIV = IMEW_HIV*XVAL;
    PHIW_HIV = IHIW_HIV*XVAL;

PLOT:
   TYPE = plot2;

OUTPUT:
   STAND CINT(bcbootstrap);

Return to Model Template index.

To cite this page and/or any code used, please use:
Stride C.B., Gardner S., Catley. N. & Thomas, F.(2015) 'Mplus code for the mediation, moderation, and moderated mediation model templates from Andrew Hayes' PROCESS analysis examples' , http://www.figureitout.org.uk