Preliminary notes:

The code below assumes that

• The latent IV (factor X) is measured by continuous observed variables X1-X4.
• Any latent moderator(s) (factors W, V, Q, Z) are measured by continuous observed variables W1-W4, Z1-Z4, V1-V4, Q1-Q4 respectively.
• Any latent mediator(s) (factor M, or factors M1, M2, etc.) are measured by continuous observed variables M1-M4 or M1_1-M1-4, M2_1-M2_4 respectively.
• The latent outcome Y is measured by continuous observed variables Y1-Y4.

Model Diagram (factor indicator variables omitted for space/clarity reasons):

Statistical Diagram (factor indicator variables omitted for space/clarity reasons):

Model Equation(s):

Y = b0 + b1M1 + b2M2 + c'X
M1 = a01 + a1X
M2 = a02 + a2X

Algebra to calculate total, indirect and/or conditional effects by writing model as Y = a + bX:

Y = b0 + b1M1 + b2M2 + c'X
M1 = a01 + a1X
M2 = a02 + a2X

Hence... substituting in equations for M1 and M2

Y = b0 + b1(a01 + a1X) + b2(a02 + a2X) + c'X

Hence... multiplying out brackets

Y = b0 + a01b1 + a1b1X + a02b2 + a2b2X + c'X

Hence... grouping terms into form Y = a + bX

Y = (b0 + a01b1 + a02b2) + (a1b1 + a2b2 + c')X

Hence...

Two indirect effects of X on Y:

a1b1, a2b2

One direct effect of X on Y:

c'

Mplus code for the model:

! Latent predictor variable X measured by X1-X4
! Latent mediator variables M1 and M2, measured by M1_1-M1_4 and M2_1-M2_4 respectively
! Latent outcome variable Y measured by Y1-Y4

USEVARIABLES = X1 X2 X3 X4 M1_1 M1_2 M1_3 M1_4 M2_1 M2_2 M2_3 M2_4
Y1 Y2 Y3 Y4;

ANALYSIS:
   TYPE = GENERAL;
   ESTIMATOR = ML;
   BOOTSTRAP = 10000;

! In model statement first state measurement model
! Then state structural model naming each path and intercept using parentheses

MODEL:

! Measurement model
   X BY X1 X2 X3 X4;
   M1 BY M1_1 M1_2 M1_3 M1_4;
   M2 BY M2_1 M2_2 M2_3 M2_4;
   Y BY Y1 Y2 Y3 Y4;

! Fit structural model and name parameters
   [Y] (b0);
   Y ON M1 (b1);
   Y ON M2 (b2);

   Y ON X (cdash);   ! direct effect of X on Y

   M1 ON X (a1);
   M2 ON X (a2);

! Use model constraint to calculate specific indirect paths and total indirect effect

MODEL CONSTRAINT:
   NEW(a1b1 a2b2 TOTALIND TOTAL);
   a1b1 = a1*b1;   ! Specific indirect effect of X on Y via M1
   a2b2 = a2*b2;   ! Specific indirect effect of X on Y via M2
   TOTALIND = a1*b1 + a2*b2;   ! Total indirect effect of X on Y via M1, M2
   TOTAL = a1*b1 + a2*b2 + cdash;   ! Total effect of X on Y

OUTPUT:
   STAND CINT(bcbootstrap);

Editing required for testing indirect effect(s) using alternative MODEL INDIRECT: subcommand

MODEL INDIRECT: offers an alternative to MODEL CONSTRAINT: for models containing indirect effects, where these are not moderated. To use MODEL INDIRECT: instead, you would edit the code above as follows:

First, you can remove the naming of parameters using parentheses in the MODEL: command, i.e. you just need:

MODEL:
   Y ON X M1 M2;
   M1 M2 ON X;

Second, replace the MODEL CONSTRAINT: subcommand with the following MODEL INDIRECT: subcommand:

   MODEL INDIRECT:
   Y IND M1 X;
   Y IND M2 X;

or, more simply,

   MODEL INDIRECT:
   Y IND X;

Leave the OUTPUT: command unchanged.

Return to Model Template index.

To cite this page and/or any code used, please use:
Stride, C.B., Gardner, S., Catley, N. & Thomas, F.(2015) 'Mplus code for the mediation, moderation, and moderated mediation model templates from Andrew Hayes' PROCESS analysis examples', http://www.offbeat.group.shef.ac.uk/FIO/mplusmedmod.htm