Preliminary notes:

The code below assumes that

• The latent IV (factor X) is measured by continuous observed variables X1-X4.
• Any latent moderator(s) (factors W, V, Q, Z) are measured by continuous observed variables W1-W4, Z1-Z4, V1-V4, Q1-Q4 respectively.
• Any latent mediator(s) (factor M, or factors M1, M2, etc.) are measured by continuous observed variables M1-M4 or M1_1-M1-4, M2_1-M2_4 respectively.
• The latent outcome Y is measured by continuous observed variables Y1-Y4.

Model Diagram (factor indicator variables omitted for space/clarity reasons):

Statistical Diagram (factor indicator variables omitted for space/clarity reasons):

Model Equation(s):

Y = b0 + b1M + b2V + b3Q + b4MV + b5MQ + c'X
M = a0 + a1X + a2W + a3XW

Algebra to calculate indirect and/or conditional effects by writing model as Y = a + bX:

Y = b0 + b1M + b2V + b3Q + b4MV + b5MQ + c'X
M = a0 + a1X + a2W + a3XW

Hence... substituting in equation for M

Y = b0 + b1(a0 + a1X + a2W + a3XW) + b2V + b3Q + b4(a0 + a1X + a2W + a3XW)V + b5(a0 + a1X + a2W + a3XW)Q + c'X

Hence... multiplying out brackets

Y = b0 + a0b1 + a1b1X + a2b1W + a3b1XW + b2V + b3Q + a0b4V + a1b4XV + a2b4WV + a3b4XWV + a0b5Q + a1b5XQ + a2b5WQ + a3b5XWQ + c'X

Hence... grouping terms into form Y = a + bX

Y = (b0 + a0b1 + a2b1W + b2V + b3Q + a0b4V + a2b4WV + a0b5Q + a2b5WQ) + (a1b1 + a3b1W + a1b4V + a3b4WV + a1b5Q + a3b5WQ + c')X

Hence...

One indirect effect(s) of X on Y, conditional on W, V, Q:

a1b1 + a3b1W + a1b4V + a3b4WV + a1b5Q + a3b5WQ = (a1 + a3W)(b1 + b4V + b5Q)

One direct effect of X on Y:

c'

Mplus code for the model:

! Latent predictor variable X measured by X1-X4
! Latent mediator M measured by 4 observed variables M1-M4
! Latent moderators W, V, and Q, each measured by sets of 4 observed variables W1-W4, V1-V4, and Q1-Q4 respectively
! Latent outcome variable Y measured by Y1-Y4

USEVARIABLES = X1 X2 X3 X4 M1 M2 M3 M4
W1 W2 W3 W4 V1 V2 V3 V4 Q1 Q2 Q3 Q4
Y1 Y2 Y3 Y4;

ANALYSIS:
   TYPE = GENERAL RANDOM;
   ESTIMATOR = ML;
   ALGORITHM = INTEGRATION;

! In model statement first state measurement model
! Then create any latent interactions required
! Then state structural model naming each path and intercept using parentheses

MODEL:

! Measurement model
! Identify moderator factors by fixing variance = 1 (instead of first loading)
! This makes these factors standardised
   X BY X1 X2 X3 X4;
   M BY M1 M2 M3 M4;
   W BY W1* W2 W3 W4;
   V BY V1* V2 V3 V4;
   Q BY Q1* Q2 Q3 Q4;
   Y BY Y1 Y2 Y3 Y4;

    W@1;   V@1;   Q@1;

! Create latent interactions
   MV | M XWITH V;
   MQ | M XWITH Q;
   XW | X XWITH W;

! Fit structural model and name parameters
! Note that intercepts of M, Y are fixed = 0 since they are latent vars
! so no code to state and name them as parameters
   Y ON M (b1);
   Y ON V (b2);
   Y ON Q (b3);
   Y ON MV (b4);
   Y ON MQ (b5);

   Y ON X (cdash);

   M ON X (a1);
   M ON W (a2);
   M ON XW (a3);

! Use model constraint subcommand to test conditional indirect effects
! You need to pick low, medium and high moderator values for W, V, Q
! for example, of 1 SD below mean, mean, 1 SD above mean

! 3 moderators, 3 values for each, gives 27 combinations
! arbitrary naming convention for conditional indirect and total effects used below:
! HWMVLQ = high value of W, medium value of V and low value of Q, etc.

MODEL CONSTRAINT:
    NEW(LOW_W MED_W HIGH_W LOW_V MED_V HIGH_V LOW_Q MED_Q HIGH_Q
    ILWLVLQ IMWLVLQ IHWLVLQ ILWMVLQ IMWMVLQ IHWMVLQ
    ILWHVLQ IMWHVLQ IHWHVLQ
    ILWLVMQ IMWLVMQ IHWLVMQ ILWMVMQ IMWMVMQ IHWMVMQ
    ILWHVMQ IMWHVMQ IHWHVMQ
    ILWLVHQ IMWLVHQ IHWLVHQ ILWMVHQ IMWMVHQ IHWMVHQ
    ILWHVHQ IMWHVHQ IHWHVHQ
    TLWLVLQ TMWLVLQ THWLVLQ TLWMVLQ TMWMVLQ THWMVLQ
    TLWHVLQ TMWHVLQ THWHVLQ
    TLWLVMQ TMWLVMQ THWLVMQ TLWMVMQ TMWMVMQ THWMVMQ
    TLWHVMQ TMWHVMQ THWHVMQ
    TLWLVHQ TMWLVHQ THWLVHQ TLWMVHQ TMWMVHQ THWMVHQ
    TLWHVHQ TMWHVHQ THWHVHQ);

    LOW_W = -1;   ! -1 SD below mean value of W
    MED_W = 0;   ! mean value of W
    HIGH_W = 1;   ! +1 SD above mean value of W

    LOW_V = -1;   ! -1 SD below mean value of V
    MED_V = 0;   ! mean value of V
    HIGH_V = 1;   ! +1 SD above mean value of V

    LOW_Q = -1;   ! -1 SD below mean value of Q
    MED_Q = 0;   ! mean value of Q
    HIGH_Q = 1;   ! +1 SD above mean value of Q

! Calc conditional indirect effects for each combination of moderator values

    ILWLVLQ = a1*b1 + a3*b1*LOW_W + a1*b4*LOW_V + a3*b4*LOW_W*LOW_V +
     a1*b5*LOW_Q + a3*b5*LOW_W*LOW_Q;
    IMWLVLQ = a1*b1 + a3*b1*MED_W + a1*b4*LOW_V + a3*b4*MED_W*LOW_V +
     a1*b5*LOW_Q + a3*b5*MED_W*LOW_Q;
    IHWLVLQ = a1*b1 + a3*b1*HIGH_W + a1*b4*LOW_V + a3*b4*HIGH_W*LOW_V +
     a1*b5*LOW_Q + a3*b5*HIGH_W*LOW_Q;

    ILWMVLQ = a1*b1 + a3*b1*LOW_W + a1*b4*MED_V + a3*b4*LOW_W*MED_V +
     a1*b5*LOW_Q + a3*b5*LOW_W*LOW_Q;
    IMWMVLQ = a1*b1 + a3*b1*MED_W + a1*b4*MED_V + a3*b4*MED_W*MED_V +
     a1*b5*LOW_Q + a3*b5*MED_W*LOW_Q;
    IHWMVLQ = a1*b1 + a3*b1*HIGH_W + a1*b4*MED_V + a3*b4*HIGH_W*MED_V +
     a1*b5*LOW_Q + a3*b5*HIGH_W*LOW_Q;

    ILWHVLQ = a1*b1 + a3*b1*LOW_W + a1*b4*HIGH_V + a3*b4*LOW_W*HIGH_V +
     a1*b5*LOW_Q + a3*b5*LOW_W*LOW_Q;
    IMWHVLQ = a1*b1 + a3*b1*MED_W + a1*b4*HIGH_V + a3*b4*MED_W*HIGH_V +
     a1*b5*LOW_Q + a3*b5*MED_W*LOW_Q;
    IHWHVLQ = a1*b1 + a3*b1*HIGH_W + a1*b4*HIGH_V + a3*b4*HIGH_W*HIGH_V +
     a1*b5*LOW_Q + a3*b5*HIGH_W*LOW_Q;

    ILWLVMQ = a1*b1 + a3*b1*LOW_W + a1*b4*LOW_V + a3*b4*LOW_W*LOW_V +
     a1*b5*MED_Q + a3*b5*LOW_W*MED_Q;
    IMWLVMQ = a1*b1 + a3*b1*MED_W + a1*b4*LOW_V + a3*b4*MED_W*LOW_V +
     a1*b5*MED_Q + a3*b5*MED_W*MED_Q;
    IHWLVMQ = a1*b1 + a3*b1*HIGH_W + a1*b4*LOW_V + a3*b4*HIGH_W*LOW_V +
     a1*b5*MED_Q + a3*b5*HIGH_W*MED_Q;

    ILWMVMQ = a1*b1 + a3*b1*LOW_W + a1*b4*MED_V + a3*b4*LOW_W*MED_V +
     a1*b5*MED_Q + a3*b5*LOW_W*MED_Q;
    IMWMVMQ = a1*b1 + a3*b1*MED_W + a1*b4*MED_V + a3*b4*MED_W*MED_V +
     a1*b5*MED_Q + a3*b5*MED_W*MED_Q;
    IHWMVMQ = a1*b1 + a3*b1*HIGH_W + a1*b4*MED_V + a3*b4*HIGH_W*MED_V +
     a1*b5*MED_Q + a3*b5*HIGH_W*MED_Q;

    ILWHVMQ = a1*b1 + a3*b1*LOW_W + a1*b4*HIGH_V + a3*b4*LOW_W*HIGH_V +
     a1*b5*MED_Q + a3*b5*LOW_W*MED_Q;
    IMWHVMQ = a1*b1 + a3*b1*MED_W + a1*b4*HIGH_V + a3*b4*MED_W*HIGH_V +
     a1*b5*MED_Q + a3*b5*MED_W*MED_Q;
    IHWHVMQ = a1*b1 + a3*b1*HIGH_W + a1*b4*HIGH_V + a3*b4*HIGH_W*HIGH_V +
     a1*b5*MED_Q + a3*b5*HIGH_W*MED_Q;

    ILWLVHQ = a1*b1 + a3*b1*LOW_W + a1*b4*LOW_V + a3*b4*LOW_W*LOW_V +
     a1*b5*HIGH_Q + a3*b5*LOW_W*HIGH_Q;
    IMWLVHQ = a1*b1 + a3*b1*MED_W + a1*b4*LOW_V + a3*b4*MED_W*LOW_V +
     a1*b5*HIGH_Q + a3*b5*MED_W*HIGH_Q;
    IHWLVHQ = a1*b1 + a3*b1*HIGH_W + a1*b4*LOW_V + a3*b4*HIGH_W*LOW_V +
     a1*b5*HIGH_Q + a3*b5*HIGH_W*HIGH_Q;

    ILWMVHQ = a1*b1 + a3*b1*LOW_W + a1*b4*MED_V + a3*b4*LOW_W*MED_V +
     a1*b5*HIGH_Q + a3*b5*LOW_W*HIGH_Q;
    IMWMVHQ = a1*b1 + a3*b1*MED_W + a1*b4*MED_V + a3*b4*MED_W*MED_V +
     a1*b5*HIGH_Q + a3*b5*MED_W*HIGH_Q;
    IHWMVHQ = a1*b1 + a3*b1*HIGH_W + a1*b4*MED_V + a3*b4*HIGH_W*MED_V +
     a1*b5*HIGH_Q + a3*b5*HIGH_W*HIGH_Q;

    ILWHVHQ = a1*b1 + a3*b1*LOW_W + a1*b4*HIGH_V + a3*b4*LOW_W*HIGH_V +
     a1*b5*HIGH_Q + a3*b5*LOW_W*HIGH_Q;
    IMWHVHQ = a1*b1 + a3*b1*MED_W + a1*b4*HIGH_V + a3*b4*MED_W*HIGH_V +
     a1*b5*HIGH_Q + a3*b5*MED_W*HIGH_Q;
    IHWHVHQ = a1*b1 + a3*b1*HIGH_W + a1*b4*HIGH_V + a3*b4*HIGH_W*HIGH_V +
     a1*b5*HIGH_Q + a3*b5*HIGH_W*HIGH_Q;

! Calc conditional total effects for each combination of moderator values

    TLWLVLQ = ILWLVLQ + cdash;
    TMWLVLQ = IMWLVLQ + cdash;
    THWLVLQ = IHWLVLQ + cdash;

    TLWMVLQ = ILWMVLQ + cdash;
    TMWMVLQ = IMWMVLQ + cdash;
    THWMVLQ = IHWMVLQ + cdash;

    TLWHVLQ = ILWHVLQ + cdash;
    TMWHVLQ = IMWHVLQ + cdash;
    THWHVLQ = IHWHVLQ + cdash;

    TLWLVMQ = ILWLVMQ + cdash;
    TMWLVMQ = IMWLVMQ + cdash;
    THWLVMQ = IHWLVMQ + cdash;

    TLWMVMQ = ILWMVMQ + cdash;
    TMWMVMQ = IMWMVMQ + cdash;
    THWMVMQ = IHWMVMQ + cdash;

    TLWHVMQ = ILWHVMQ + cdash;
    TMWHVMQ = IMWHVMQ + cdash;
    THWHVMQ = IHWHVMQ + cdash;

    TLWLVHQ = ILWLVHQ + cdash;
    TMWLVHQ = IMWLVHQ + cdash;
    THWLVHQ = IHWLVHQ + cdash;

    TLWMVHQ = ILWMVHQ + cdash;
    TMWMVHQ = IMWMVHQ + cdash;
    THWMVHQ = IHWMVHQ + cdash;

    TLWHVHQ = ILWHVHQ + cdash;
    TMWHVHQ = IMWHVHQ + cdash;
    THWHVHQ = IHWHVHQ + cdash;

! Use loop plot to plot conditional indirect effect of X on Y for each combination of low, med, high moderator values
! Could be edited to show conditional direct or conditional total effects instead
! NOTE - values from -3 to 3 in LOOP() statement since
! X is factor with mean set at default of 0

    PLOT(PLWLVLQ PMWLVLQ PHWLVLQ PLWMVLQ PMWMVLQ PHWMVLQ
    PLWHVLQ PMWHVLQ PHWHVLQ
    PLWLVMQ PMWLVMQ PHWLVMQ PLWMVMQ PMWMVMQ PHWMVMQ
    PLWHVMQ PMWHVMQ PHWHVMQ
    PLWLVHQ PMWLVHQ PHWLVHQ PLWMVHQ PMWMVHQ PHWMVHQ
    PLWHVHQ PMWHVHQ PHWHVHQ);

    LOOP(XVAL,-3,3,0.1);

    PLWLVLQ = ILWLVLQ*XVAL;
    PMWLVLQ = IMWLVLQ*XVAL;
    PHWLVLQ = IHWLVLQ*XVAL;

    PLWMVLQ = ILWMVLQ*XVAL;
    PMWMVLQ = IMWMVLQ*XVAL;
    PHWMVLQ = IHWMVLQ*XVAL;

    PLWHVLQ = ILWHVLQ*XVAL;
    PMWHVLQ = IMWHVLQ*XVAL;
    PHWHVLQ = IHWHVLQ*XVAL;

    PLWLVMQ = ILWLVMQ*XVAL;
    PMWLVMQ = IMWLVMQ*XVAL;
    PHWLVMQ = IHWLVMQ*XVAL;

    PLWMVMQ = ILWMVMQ*XVAL;
    PMWMVMQ = IMWMVMQ*XVAL;
    PHWMVMQ = IHWMVMQ*XVAL;

    PLWHVMQ = ILWHVMQ*XVAL;
    PMWHVMQ = IMWHVMQ*XVAL;
    PHWHVMQ = IHWHVMQ*XVAL;

    PLWLVHQ = ILWLVHQ*XVAL;
    PMWLVHQ = IMWLVHQ*XVAL;
    PHWLVHQ = IHWLVHQ*XVAL;

    PLWMVHQ = ILWMVHQ*XVAL;
    PMWMVHQ = IMWMVHQ*XVAL;
    PHWMVHQ = IHWMVHQ*XVAL;

    PLWHVHQ = ILWHVHQ*XVAL;
    PMWHVHQ = IMWHVHQ*XVAL;
    PHWHVHQ = IHWHVHQ*XVAL;

PLOT:
   TYPE = plot2;

OUTPUT:
   CINT;

Return to Model Template index.

To cite this page and/or any code used, please use:
Stride C.B., Gardner S., Catley. N. & Thomas, F.(2015) 'Mplus code for the mediation, moderation, and moderated mediation model templates from Andrew Hayes' PROCESS analysis examples' , http://www.figureitout.org.uk