Preliminary notes:

The code below assumes that

• The latent IV (factor X) is measured by continuous observed variables X1-X4.
• Any latent moderator(s) (factors W, V, Q, Z) are measured by continuous observed variables W1-W4, Z1-Z4, V1-V4, Q1-Q4 respectively.
• Any latent mediator(s) (factor M, or factors M1, M2, etc.) are measured by continuous observed variables M1-M4 or M1_1-M1-4, M2_1-M2_4 respectively.
• The latent outcome Y is measured by continuous observed variables Y1-Y4.

Model Diagram (factor indicator variables omitted for space/clarity reasons):

Statistical Diagram (factor indicator variables omitted for space/clarity reasons):

Model Equation(s):

Y = b0 + b1M + b2V + b3MV + c'X
M = a0 + a1X + a2W + a3Z + a4XW + a5XZ + a6WZ + a7XWZ

Algebra to calculate indirect and/or conditional effects by writing model as Y = a + bX:

Y = b0 + b1M + b2V + b3MV + c'X
M = a0 + a1X + a2W + a3Z + a4XW + a5XZ + a6WZ + a7XWZ

Hence... substituting in equation for M

Y = b0 + b1(a0 + a1X + a2W + a3Z + a4XW + a5XZ + a6WZ + a7XWZ) + b2V + b3(a0 + a1X + a2W + a3Z + a4XW + a5XZ + a6WZ + a7XWZ)V + c'X

Hence... multiplying out brackets

Y = b0 + a0b1 + a1b1X + a2b1W + a3b1Z + a4b1XW + a5b1XZ + a6b1WZ + a7b1XWZ + b2V + a0b3V + a1b3XV + a2b3WV + a3b3ZV + a4b3XWV + a5b3XZV + a6b3WZV + a7b3XWZV + c'X

Hence... grouping terms into form Y = a + bX

Y = (b0 + a0b1 + a2b1W + a3b1Z + a6b1WZ + b2V + a0b3V + a2b3WV + a3b3ZV + a6b3WZV) + (a1b1 + a4b1W + a5b1Z + a7b1WZ + a1b3V + a4b3WV + a5b3ZV + a7b3WZV + c')X

Hence...

One indirect effect(s) of X on Y, conditional on W, Z, V:

a1b1 + a4b1W + a5b1Z + a7b1WZ + a1b3V + a4b3WV + a5b3ZV + a7b3WZV = (a1 + a4W + a5Z + a7WZ)(b1 + b3V)

One direct effect of X on Y:

c'

Mplus code for the model:

! Latent predictor variable X measured by X1-X4
! Latent mediator M measured by 4 observed variables M1-M4
! Latent moderators W, Z, and V, each measured by sets of 4 observed variables W1-W4, Z1-Z4, and V1-V4 respectively
! Latent outcome variable Y measured by Y1-Y4

USEVARIABLES = X1 X2 X3 X4 M1 M2 M3 M4
W1 W2 W3 W4 Z1 Z2 Z3 Z4 V1 V2 V3 V4
Y1 Y2 Y3 Y4;

ANALYSIS:
   TYPE = GENERAL RANDOM;
   ESTIMATOR = ML;
   ALGORITHM = INTEGRATION;

! In model statement first state measurement model
! Then create any latent interactions required
! Then state structural model naming each path and intercept using parentheses

MODEL:

! Measurement model
! Identify moderator factors by fixing variance = 1 (instead of first loading)
! This makes these factors standardised
   X BY X1 X2 X3 X4;
   M BY M1 M2 M3 M4;
   W BY W1* W2 W3 W4;
   Z BY Z1* Z2 Z3 Z4;
   V BY V1* V2 V3 V4;
   Y BY Y1 Y2 Y3 Y4;

    W@1;   Z@1;   V@1;

! Create latent interactions
   MV | M XWITH V;
   XW | X XWITH W;
   XZ | X XWITH Z;
   WZ | W XWITH Z;
   XWZ | X XWITH WZ;

! Fit structural model and name parameters
! Note that intercepts of M, Y are fixed = 0 since they are latent vars
! so no code to state and name them as parameters
   Y ON M (b1);
   Y ON V (b2);
   Y ON MV (b3);

   Y ON X (cdash);

   M ON X (a1);
   M ON W (a2);
   M ON Z (a3);
   M ON XW (a4);
   M ON XZ (a5);
   M ON WZ (a6);
   M ON XWZ (a7);

! Use model constraint subcommand to test conditional indirect effects
! You need to pick low, medium and high moderator values for W, Z, V
! for example, of 1 SD below mean, mean, 1 SD above mean

! 3 moderators, 3 values for each, gives 27 combinations
! arbitrary naming convention for conditional indirect and total effects used below:
! HWMVLQ = high value of W, medium value of V and low value of Q, etc.

MODEL CONSTRAINT:
    NEW(LOW_W MED_W HIGH_W LOW_Z MED_Z HIGH_Z LOW_V MED_V HIGH_V
    ILWLZLV IMWLZLV IHWLZLV ILWMZLV IMWMZLV IHWMZLV
    ILWHZLV IMWHZLV IHWHZLV
    ILWLZMV IMWLZMV IHWLZMV ILWMZMV IMWMZMV IHWMZMV
    ILWHZMV IMWHZMV IHWHZMV
    ILWLZHV IMWLZHV IHWLZHV ILWMZHV IMWMZHV IHWMZHV
    ILWHZHV IMWHZHV IHWHZHV
    TLWLZLV TMWLZLV THWLZLV TLWMZLV TMWMZLV THWMZLV
    TLWHZLV TMWHZLV THWHZLV
    TLWLZMV TMWLZMV THWLZMV TLWMZMV TMWMZMV THWMZMV
    TLWHZMV TMWHZMV THWHZMV
    TLWLZHV TMWLZHV THWLZHV TLWMZHV TMWMZHV THWMZHV
    TLWHZHV TMWHZHV THWHZHV);

    LOW_W = -1;   ! -1 SD below mean value of W
    MED_W = 0;   ! mean value of W
    HIGH_W = 1;   ! +1 SD above mean value of W

    LOW_Z = -1;   ! -1 SD below mean value of Z
    MED_Z = 0;   ! mean value of Z
    HIGH_Z = 1;   ! +1 SD above mean value of Z

    LOW_V = -1;   ! -1 SD below mean value of V
    MED_V = 0;   ! mean value of V
    HIGH_V = 1;   ! +1 SD above mean value of V

! Calc conditional indirect effects for each combination of moderator values

    ILWLZLV = a1*b1 + a4*b1*LOW_W + a5*b1*LOW_Z + a7*b1*LOW_W*LOW_Z +
     a1*b3*LOW_V + a4*b3*LOW_W*LOW_V + a5*b3*LOW_Z*LOW_V +
     a7*b3*LOW_W*LOW_Z*LOW_V;
    IMWLZLV = a1*b1 + a4*b1*MED_W + a5*b1*LOW_Z + a7*b1*MED_W*LOW_Z +
     a1*b3*LOW_V + a4*b3*MED_W*LOW_V + a5*b3*LOW_Z*LOW_V +
     a7*b3*MED_W*LOW_Z*LOW_V;
    IHWLZLV = a1*b1 + a4*b1*HIGH_W + a5*b1*LOW_Z + a7*b1*HIGH_W*LOW_Z +
     a1*b3*LOW_V + a4*b3*HIGH_W*LOW_V + a5*b3*LOW_Z*LOW_V +
     a7*b3*HIGH_W*LOW_Z*LOW_V;

    ILWMZLV = a1*b1 + a4*b1*LOW_W + a5*b1*MED_Z + a7*b1*LOW_W*MED_Z +
     a1*b3*LOW_V + a4*b3*LOW_W*LOW_V + a5*b3*MED_Z*LOW_V +
     a7*b3*LOW_W*MED_Z*LOW_V;
    IMWMZLV = a1*b1 + a4*b1*MED_W + a5*b1*MED_Z + a7*b1*MED_W*MED_Z +
     a1*b3*LOW_V + a4*b3*MED_W*LOW_V + a5*b3*MED_Z*LOW_V +
     a7*b3*MED_W*MED_Z*LOW_V;
    IHWMZLV = a1*b1 + a4*b1*HIGH_W + a5*b1*MED_Z + a7*b1*HIGH_W*MED_Z +
     a1*b3*LOW_V + a4*b3*HIGH_W*LOW_V + a5*b3*MED_Z*LOW_V +
     a7*b3*HIGH_W*MED_Z*LOW_V;

    ILWHZLV = a1*b1 + a4*b1*LOW_W + a5*b1*HIGH_Z + a7*b1*LOW_W*HIGH_Z +
     a1*b3*LOW_V + a4*b3*LOW_W*LOW_V + a5*b3*HIGH_Z*LOW_V +
     a7*b3*LOW_W*HIGH_Z*LOW_V;
    IMWHZLV = a1*b1 + a4*b1*MED_W + a5*b1*HIGH_Z + a7*b1*MED_W*HIGH_Z +
     a1*b3*LOW_V + a4*b3*MED_W*LOW_V + a5*b3*HIGH_Z*LOW_V +
     a7*b3*MED_W*HIGH_Z*LOW_V;
    IHWHZLV = a1*b1 + a4*b1*HIGH_W + a5*b1*HIGH_Z + a7*b1*HIGH_W*HIGH_Z +
     a1*b3*LOW_V + a4*b3*HIGH_W*LOW_V + a5*b3*HIGH_Z*LOW_V +
     a7*b3*HIGH_W*HIGH_Z*LOW_V;

    ILWLZMV = a1*b1 + a4*b1*LOW_W + a5*b1*LOW_Z + a7*b1*LOW_W*LOW_Z +
     a1*b3*MED_V + a4*b3*LOW_W*MED_V + a5*b3*LOW_Z*MED_V +
     a7*b3*LOW_W*LOW_Z*MED_V;
    IMWLZMV = a1*b1 + a4*b1*MED_W + a5*b1*LOW_Z + a7*b1*MED_W*LOW_Z +
     a1*b3*MED_V + a4*b3*MED_W*MED_V + a5*b3*LOW_Z*MED_V +
     a7*b3*MED_W*LOW_Z*MED_V;
    IHWLZMV = a1*b1 + a4*b1*HIGH_W + a5*b1*LOW_Z + a7*b1*HIGH_W*LOW_Z +
     a1*b3*MED_V + a4*b3*HIGH_W*MED_V + a5*b3*LOW_Z*MED_V +
     a7*b3*HIGH_W*LOW_Z*MED_V;

    ILWMZMV = a1*b1 + a4*b1*LOW_W + a5*b1*MED_Z + a7*b1*LOW_W*MED_Z +
     a1*b3*MED_V + a4*b3*LOW_W*MED_V + a5*b3*MED_Z*MED_V +
     a7*b3*LOW_W*MED_Z*MED_V;
    IMWMZMV = a1*b1 + a4*b1*MED_W + a5*b1*MED_Z + a7*b1*MED_W*MED_Z +
     a1*b3*MED_V + a4*b3*MED_W*MED_V + a5*b3*MED_Z*MED_V +
     a7*b3*MED_W*MED_Z*MED_V;
    IHWMZMV = a1*b1 + a4*b1*HIGH_W + a5*b1*MED_Z + a7*b1*HIGH_W*MED_Z +
     a1*b3*MED_V + a4*b3*HIGH_W*MED_V + a5*b3*MED_Z*MED_V +
     a7*b3*HIGH_W*MED_Z*MED_V;

    ILWHZMV = a1*b1 + a4*b1*LOW_W + a5*b1*HIGH_Z + a7*b1*LOW_W*HIGH_Z +
     a1*b3*MED_V + a4*b3*LOW_W*MED_V + a5*b3*HIGH_Z*MED_V +
     a7*b3*LOW_W*HIGH_Z*MED_V;
    IMWHZMV = a1*b1 + a4*b1*MED_W + a5*b1*HIGH_Z + a7*b1*MED_W*HIGH_Z +
     a1*b3*MED_V + a4*b3*MED_W*MED_V + a5*b3*HIGH_Z*MED_V +
     a7*b3*MED_W*HIGH_Z*MED_V;
    IHWHZMV = a1*b1 + a4*b1*HIGH_W + a5*b1*HIGH_Z + a7*b1*HIGH_W*HIGH_Z +
     a1*b3*MED_V + a4*b3*HIGH_W*MED_V + a5*b3*HIGH_Z*MED_V +
     a7*b3*HIGH_W*HIGH_Z*MED_V;

    ILWLZHV = a1*b1 + a4*b1*LOW_W + a5*b1*LOW_Z + a7*b1*LOW_W*LOW_Z +
     a1*b3*HIGH_V + a4*b3*LOW_W*HIGH_V + a5*b3*LOW_Z*HIGH_V +
     a7*b3*LOW_W*LOW_Z*HIGH_V;
    IMWLZHV = a1*b1 + a4*b1*MED_W + a5*b1*LOW_Z + a7*b1*MED_W*LOW_Z +
     a1*b3*HIGH_V + a4*b3*MED_W*HIGH_V + a5*b3*LOW_Z*HIGH_V +
     a7*b3*MED_W*LOW_Z*HIGH_V;
    IHWLZHV = a1*b1 + a4*b1*HIGH_W + a5*b1*LOW_Z + a7*b1*HIGH_W*LOW_Z +
     a1*b3*HIGH_V + a4*b3*HIGH_W*HIGH_V + a5*b3*LOW_Z*HIGH_V +
     a7*b3*HIGH_W*LOW_Z*HIGH_V;

    ILWMZHV = a1*b1 + a4*b1*LOW_W + a5*b1*MED_Z + a7*b1*LOW_W*MED_Z +
     a1*b3*HIGH_V + a4*b3*LOW_W*HIGH_V + a5*b3*MED_Z*HIGH_V +
     a7*b3*LOW_W*MED_Z*HIGH_V;
    IMWMZHV = a1*b1 + a4*b1*MED_W + a5*b1*MED_Z + a7*b1*MED_W*MED_Z +
     a1*b3*HIGH_V + a4*b3*MED_W*HIGH_V + a5*b3*MED_Z*HIGH_V +
     a7*b3*MED_W*MED_Z*HIGH_V;
    IHWMZHV = a1*b1 + a4*b1*HIGH_W + a5*b1*MED_Z + a7*b1*HIGH_W*MED_Z +
     a1*b3*HIGH_V + a4*b3*HIGH_W*HIGH_V + a5*b3*MED_Z*HIGH_V +
     a7*b3*HIGH_W*MED_Z*HIGH_V;

    ILWHZHV = a1*b1 + a4*b1*LOW_W + a5*b1*HIGH_Z + a7*b1*LOW_W*HIGH_Z +
     a1*b3*HIGH_V + a4*b3*LOW_W*HIGH_V + a5*b3*HIGH_Z*HIGH_V +
     a7*b3*LOW_W*HIGH_Z*HIGH_V;
    IMWHZHV = a1*b1 + a4*b1*MED_W + a5*b1*HIGH_Z + a7*b1*MED_W*HIGH_Z +
     a1*b3*HIGH_V + a4*b3*MED_W*HIGH_V + a5*b3*HIGH_Z*HIGH_V +
     a7*b3*MED_W*HIGH_Z*HIGH_V;
    IHWHZHV = a1*b1 + a4*b1*HIGH_W + a5*b1*HIGH_Z + a7*b1*HIGH_W*HIGH_Z +
     a1*b3*HIGH_V + a4*b3*HIGH_W*HIGH_V + a5*b3*HIGH_Z*HIGH_V +
     a7*b3*HIGH_W*HIGH_Z*HIGH_V;

! Calc conditional total effects for each combination of moderator values

    TLWLZLV = ILWLZLV + cdash;
    TMWLZLV = IMWLZLV + cdash;
    THWLZLV = IHWLZLV + cdash;

    TLWMZLV = ILWMZLV + cdash;
    TMWMZLV = IMWMZLV + cdash;
    THWMZLV = IHWMZLV + cdash;

    TLWHZLV = ILWHZLV + cdash;
    TMWHZLV = IMWHZLV + cdash;
    THWHZLV = IHWHZLV + cdash;

    TLWLZMV = ILWLZMV + cdash;
    TMWLZMV = IMWLZMV + cdash;
    THWLZMV = IHWLZMV + cdash;

    TLWMZMV = ILWMZMV + cdash;
    TMWMZMV = IMWMZMV + cdash;
    THWMZMV = IHWMZMV + cdash;

    TLWHZMV = ILWHZMV + cdash;
    TMWHZMV = IMWHZMV + cdash;
    THWHZMV = IHWHZMV + cdash;

    TLWLZHV = ILWLZHV + cdash;
    TMWLZHV = IMWLZHV + cdash;
    THWLZHV = IHWLZHV + cdash;

    TLWMZHV = ILWMZHV + cdash;
    TMWMZHV = IMWMZHV + cdash;
    THWMZHV = IHWMZHV + cdash;

    TLWHZHV = ILWHZHV + cdash;
    TMWHZHV = IMWHZHV + cdash;
    THWHZHV = IHWHZHV + cdash;

! Use loop plot to plot conditional indirect effect of X on Y for each combination of low, med, high moderator values
! Could be edited to show conditional direct or conditional total effects instead
! NOTE - values from -3 to 3 in LOOP() statement since
! X is factor with mean set at default of 0

    PLOT(PLWLZLV PMWLZLV PHWLZLV PLWMZLV PMWMZLV PHWMZLV
    PLWHZLV PMWHZLV PHWHZLV
    PLWLZMV PMWLZMV PHWLZMV PLWMZMV PMWMZMV PHWMZMV
    PLWHZMV PMWHZMV PHWHZMV
    PLWLZHV PMWLZHV PHWLZHV PLWMZHV PMWMZHV PHWMZHV
    PLWHZHV PMWHZHV PHWHZHV);

    LOOP(XVAL,-3,3,0.1);

    PLWLZLV = ILWLZLV*XVAL;
    PMWLZLV = IMWLZLV*XVAL;
    PHWLZLV = IHWLZLV*XVAL;

    PLWMZLV = ILWMZLV*XVAL;
    PMWMZLV = IMWMZLV*XVAL;
    PHWMZLV = IHWMZLV*XVAL;

    PLWHZLV = ILWHZLV*XVAL;
    PMWHZLV = IMWHZLV*XVAL;
    PHWHZLV = IHWHZLV*XVAL;

    PLWLZMV = ILWLZMV*XVAL;
    PMWLZMV = IMWLZMV*XVAL;
    PHWLZMV = IHWLZMV*XVAL;

    PLWMZMV = ILWMZMV*XVAL;
    PMWMZMV = IMWMZMV*XVAL;
    PHWMZMV = IHWMZMV*XVAL;

    PLWHZMV = ILWHZMV*XVAL;
    PMWHZMV = IMWHZMV*XVAL;
    PHWHZMV = IHWHZMV*XVAL;

    PLWLZHV = ILWLZHV*XVAL;
    PMWLZHV = IMWLZHV*XVAL;
    PHWLZHV = IHWLZHV*XVAL;

    PLWMZHV = ILWMZHV*XVAL;
    PMWMZHV = IMWMZHV*XVAL;
    PHWMZHV = IHWMZHV*XVAL;

    PLWHZHV = ILWHZHV*XVAL;
    PMWHZHV = IMWHZHV*XVAL;
    PHWHZHV = IHWHZHV*XVAL;

PLOT:
   TYPE = plot2;

OUTPUT:
   CINT;

Return to Model Template index.

To cite this page and/or any code used, please use:
Stride C.B., Gardner S., Catley. N. & Thomas, F.(2015) 'Mplus code for the mediation, moderation, and moderated mediation model templates from Andrew Hayes' PROCESS analysis examples' , http://www.figureitout.org.uk