Preliminary notes:

The code below assumes that

• The latent IV (factor X) is measured by continuous observed variables X1-X4.
• Any latent moderator(s) (factors W, V, Q, Z) are measured by continuous observed variables W1-W4, Z1-Z4, V1-V4, Q1-Q4 respectively.
• Any latent mediator(s) (factor M, or factors M1, M2, etc.) are measured by continuous observed variables M1-M4 or M1_1-M1-4, M2_1-M2_4 respectively.
• The latent outcome Y is measured by continuous observed variables Y1-Y4.

Model Diagram (factor indicator variables omitted for space/clarity reasons):

Statistical Diagram (factor indicator variables omitted for space/clarity reasons):

Model Equation(s):

Y = b0 + b1M + b2MV + b3MQ + b4MVQ + c1'X + c2'V + c3'Q + c4'XV + c5'XQ + c6'VQ + c7'XVQ
M = a0 + a1X

Algebra to calculate indirect and/or conditional effects by writing model as Y = a + bX:

Y = b0 + b1M + b2MV + b3MQ + b4MVQ + c1'X + c2'V + c3'Q + c4'XV + c5'XQ + c6'VQ + c7'XVQ
M = a0 + a1X

Hence... substituting in equation for M

Y = b0 + b1(a0 + a1X) + b2(a0 + a1X)V + b3(a0 + a1X)Q + b4(a0 + a1X)VQ + c1'X + c2'V + c3'Q + c4'XV + c5'XQ + c6'VQ + c7'XVQ

Hence... multiplying out brackets

Y = b0 + a0b1 + a1b1X + a0b2V + a1b2XV + a0b3Q + a1b3XQ + a0b4VQ + a1b4XVQ + c1'X + c2'V + c3'Q + c4'XV + c5'XQ + c6'VQ + c7'XVQ

Hence... grouping terms into form Y = a + bX

Y = (b0 + a0b1 + a0b2V + a0b3Q + a0b4VQ + c2'V + c3'Q + c6'VQ) + (a1b1 + a1b2V + a1b3Q + a1b4VQ + c1' + c4'V + c5'Q + c7'VQ)X

Hence...

One indirect effect(s) of X on Y, conditional on V, Q:

a1b1 + a1b2V + a1b3Q + a1b4VQ = a1(b1 + b2V + b3Q + b4VQ)

One direct effect of X on Y, conditional on V, Q:

c1' + c4'V + c5'Q + c7'VQ

Mplus code for the model:

! Latent predictor variable X measured by X1-X4
! Latent mediator M measured by 4 observed variables M1-M4
! Latent moderators V and Q, each measured by sets of observed variables V1-V4 and Q1-Q4 respectively
! Latent outcome variable Y measured by Y1-Y4

USEVARIABLES = X1 X2 X3 X4 M1 M2 M3 M4
V1 V2 V3 V4 Q1 Q2 Q3 Q4
Y1 Y2 Y3 Y4;

ANALYSIS:
   TYPE = GENERAL RANDOM;
   ESTIMATOR = ML;
   ALGORITHM = INTEGRATION;

! In model statement first state measurement model
! Then create any latent interactions required
! Then state structural model naming each path and intercept using parentheses

MODEL:

! Measurement model
! Identify moderator factors by fixing variance = 1 (instead of first loading)
! This makes these factors standardised
   X BY X1 X2 X3 X4;
   M BY M1 M2 M3 M4;
   V BY V1* V2 V3 V4;
   Q BY Q1* Q2 Q3 Q4;
   Y BY Y1 Y2 Y3 Y4;

    V@1;   Q@1;

! Create latent interactions
   MV | M XWITH V;
   MQ | M XWITH Q;
   XV | X XWITH V;
   XQ | X XWITH Q;
   VQ | V XWITH Q;
   MVQ | M XWITH VQ;
   XVQ | X XWITH VQ;

! Fit structural model and name parameters
! Note that intercepts of M, Y are fixed = 0 since they are latent vars
! so no code to state and name them as parameters
   Y ON M (b1);
   Y ON MV (b2);
   Y ON MQ (b3);
   Y ON MVQ (b4);

   Y ON X (cdash1);
   Y ON V (cdash2);
   Y ON Q (cdash3);
   Y ON XV (cdash4);
   Y ON XQ (cdash5);
   Y ON VQ (cdash6);
   Y ON XVQ (cdash7);

   M ON X (a1);

! Use model constraint subcommand to test conditional indirect effects
! You need to pick low, medium and high moderator values for V, Q
! for example, of 1 SD below mean, mean, 1 SD above mean

! 2 moderators, 3 values for each, gives 9 combinations
! arbitrary naming convention for conditional indirect and total effects used below:
! MEV_LOQ = medium value of V and low value of Q, etc.

MODEL CONSTRAINT:
    NEW(LOW_V MED_V HIGH_V LOW_Q MED_Q HIGH_Q
    ILOV_LOQ IMEV_LOQ IHIV_LOQ ILOV_MEQ IMEV_MEQ IHIV_MEQ
    ILOV_HIQ IMEV_HIQ IHIV_HIQ
    DLOV_LOQ DMEV_LOQ DHIV_LOQ DLOV_MEQ DMEV_MEQ DHIV_MEQ
    DLOV_HIQ DMEV_HIQ DHIV_HIQ
    TLOV_LOQ TMEV_LOQ THIV_LOQ TLOV_MEQ TMEV_MEQ THIV_MEQ
    TLOV_HIQ TMEV_HIQ THIV_HIQ);

    LOW_V = -1;   ! -1 SD below mean value of V
    MED_V = 0;   ! mean value of V
    HIGH_V = 1;   ! +1 SD above mean value of V

    LOW_Q = -1;   ! -1 SD below mean value of Q
    MED_Q = 0;   ! mean value of Q
    HIGH_Q = 1;   ! +1 SD above mean value of Q

! Calc conditional indirect effects for each combination of moderator values

    ILOV_LOQ = a1*b1 + a1*b2*LOW_V + a1*b3*LOW_Q + a1*b4*LOW_V*LOW_Q;
    IMEV_LOQ = a1*b1 + a1*b2*MED_V + a1*b3*LOW_Q + a1*b4*MED_V*LOW_Q;
    IHIV_LOQ = a1*b1 + a1*b2*HIGH_V + a1*b3*LOW_Q + a1*b4*HIGH_V*LOW_Q;

    ILOV_MEQ = a1*b1 + a1*b2*LOW_V + a1*b3*MED_Q + a1*b4*LOW_V*MED_Q;
    IMEV_MEQ = a1*b1 + a1*b2*MED_V + a1*b3*MED_Q + a1*b4*MED_V*MED_Q;
    IHIV_MEQ = a1*b1 + a1*b2*HIGH_V + a1*b3*MED_Q + a1*b4*HIGH_V*MED_Q;

    ILOV_HIQ = a1*b1 + a1*b2*LOW_V + a1*b3*HIGH_Q + a1*b4*LOW_V*HIGH_Q;
    IMEV_HIQ = a1*b1 + a1*b2*MED_V + a1*b3*HIGH_Q + a1*b4*MED_V*HIGH_Q;
    IHIV_HIQ = a1*b1 + a1*b2*HIGH_V + a1*b3*HIGH_Q + a1*b4*HIGH_V*HIGH_Q;

! Calc conditional direct effects for each combination of moderator values

    DLOV_LOQ = cdash1 + cdash4*LOW_V + cdash5*LOW_Q + cdash7*LOW_V*LOW_Q;
    DMEV_LOQ = cdash1 + cdash4*MED_V + cdash5*LOW_Q + cdash7*MED_V*LOW_Q;
    DHIV_LOQ = cdash1 + cdash4*HIGH_V + cdash5*LOW_Q + cdash7*HIGH_V*LOW_Q;

    DLOV_MEQ = cdash1 + cdash4*LOW_V + cdash5*MED_Q + cdash7*LOW_V*MED_Q;
    DMEV_MEQ = cdash1 + cdash4*MED_V + cdash5*MED_Q + cdash7*MED_V*MED_Q;
    DHIV_MEQ = cdash1 + cdash4*HIGH_V + cdash5*MED_Q + cdash7*HIGH_V*MED_Q;

    DLOV_HIQ = cdash1 + cdash4*LOW_V + cdash5*HIGH_Q + cdash7*LOW_V*HIGH_Q;
    DMEV_HIQ = cdash1 + cdash4*MED_V + cdash5*HIGH_Q + cdash7*MED_V*HIGH_Q;
    DHIV_HIQ = cdash1 + cdash4*HIGH_V + cdash5*HIGH_Q + cdash7*HIGH_V*HIGH_Q;

! Calc conditional total effects for each combination of moderator values

    TLOV_LOQ = ILOV_LOQ + DLOV_LOQ;
    TMEV_LOQ = IMEV_LOQ + DMEV_LOQ;
    THIV_LOQ = IHIV_LOQ + DHIV_LOQ;

    TLOV_MEQ = ILOV_MEQ + DLOV_MEQ;
    TMEV_MEQ = IMEV_MEQ + DMEV_MEQ;
    THIV_MEQ = IHIV_MEQ + DHIV_MEQ;

    TLOV_HIQ = ILOV_HIQ + DLOV_HIQ;
    TMEV_HIQ = IMEV_HIQ + DMEV_HIQ;
    THIV_HIQ = IHIV_HIQ + DHIV_HIQ;

! Use loop plot to plot conditional indirect effect of X on Y for each combination of low, med, high moderator values
! Could be edited to show conditional direct or conditional total effects instead
! NOTE - values from -3 to 3 in LOOP() statement since
! X is factor with mean set at default of 0

    PLOT(PLOV_LOQ PMEV_LOQ PHIV_LOQ PLOV_MEQ PMEV_MEQ PHIV_MEQ
    PLOV_HIQ PMEV_HIQ PHIV_HIQ);

    LOOP(XVAL,-3,3,0.1);

    PLOV_LOQ = ILOV_LOQ*XVAL;
    PMEV_LOQ = IMEV_LOQ*XVAL;
    PHIV_LOQ = IHIV_LOQ*XVAL;

    PLOV_MEQ = ILOV_MEQ*XVAL;
    PMEV_MEQ = IMEV_MEQ*XVAL;
    PHIV_MEQ = IHIV_MEQ*XVAL;

    PLOV_HIQ = ILOV_HIQ*XVAL;
    PMEV_HIQ = IMEV_HIQ*XVAL;
    PHIV_HIQ = IHIV_HIQ*XVAL;

PLOT:
   TYPE = plot2;

OUTPUT:
   CINT;

Return to Model Template index.

To cite this page and/or any code used, please use:
Stride C.B., Gardner S., Catley. N. & Thomas, F.(2015) 'Mplus code for the mediation, moderation, and moderated mediation model templates from Andrew Hayes' PROCESS analysis examples' , http://www.figureitout.org.uk