﻿figure it out - a statistical consultancy from the Institute of Work Psychology, University of Sheffield

## Mplus code for mediation, moderation, and moderated mediation models

Model 19: 1 or more mediators, in parallel if multiple (example uses 1), 2 moderators both moderating the Mediator-DV path and direct IV-DV path, all 2-way and 3-way interactions

Example Variables: 1 predictor X, 1 mediator M, 2 moderators V, Q, 1 outcome Y

Preliminary notes:

The code below assumes that

• The primary IV (variable X) is continuous or dichotomous.
• Any moderators (variables W, V, Q, Z) are continuous, though the only adaptation required to handle dichotomous moderators is in the MODEL CONSTRAINT: and loop plot code - an example of how to do this is given in model 1b. Handling categorical moderators with > 2 categories is demonstrated in model 1d.
• Any mediators (variable M, or M1, M2, etc.) are continuous and satisfy the assumptions of standard multiple regression. An example of how to handle a dichotomous mediator is given in model 4c.
• The DV (variable Y) is continuous and satisfies the assumptions of standard multiple regression - an example of how to handle a dichotomous DV is given in model 1e (i.e. a moderated logistic regression) and in model 4d (i.e. an indirect effect in a logistic regression).

Model Diagram:

Statistical Diagram:

Model Equation(s):

Y = b0 + b1M + b2MV + b3MQ + b4MVQ + c1'X + c2'V + c3'Q + c4'XV + c5'XQ + c6'VQ + c7'XVQ
M = a0 + a1X

Algebra to calculate indirect and/or conditional effects by writing model as Y = a + bX:

Y = b0 + b1M + b2MV + b3MQ + b4MVQ + c1'X + c2'V + c3'Q + c4'XV + c5'XQ + c6'VQ + c7'XVQ
M = a0 + a1X

Hence... substituting in equation for M

Y = b0 + b1(a0 + a1X) + b2(a0 + a1X)V + b3(a0 + a1X)Q + b4(a0 + a1X)VQ + c1'X + c2'V + c3'Q + c4'XV + c5'XQ + c6'VQ + c7'XVQ

Hence... multiplying out brackets

Y = b0 + a0b1 + a1b1X + a0b2V + a1b2XV + a0b3Q + a1b3XQ + a0b4VQ + a1b4XVQ + c1'X + c2'V + c3'Q + c4'XV + c5'XQ + c6'VQ + c7'XVQ

Hence... grouping terms into form Y = a + bX

Y = (b0 + a0b1 + a0b2V + a0b3Q + a0b4VQ + c2'V + c3'Q + c6'VQ) + (a1b1 + a1b2V + a1b3Q + a1b4VQ + c1' + c4'V + c5'Q + c7'VQ)X

Hence...

One indirect effect(s) of X on Y, conditional on V, Q:

a1b1 + a1b2V + a1b3Q + a1b4VQ = a1(b1 + b2V + b3Q + b4VQ)

One direct effect of X on Y, conditional on V, Q:

c1' + c4'V + c5'Q + c7'VQ

Mplus code for the model:

! Predictor variable - X
! Mediator variable(s) – M
! Moderator variable(s) – V, Q
! Outcome variable - Y

USEVARIABLES = X M V Q Y MV MQ XV XQ VQ MVQ XVQ;

! Create interaction terms
! Note that they have to be placed at end of USEVARIABLES subcommand above

DEFINE:
MQ = M*Q;
MV = M*V;
XQ = X*Q;
XV = X*V;
VQ = V*Q;
MVQ = M*V*Q;
XVQ = X*V*Q;

ANALYSIS:
TYPE = GENERAL;
ESTIMATOR = ML;
BOOTSTRAP = 10000;

! In model statement name each path and intercept using parentheses

MODEL:
[Y] (b0);
Y ON M (b1);
Y ON MV (b2);
Y ON MQ (b3);
Y ON MVQ (b4);

Y ON X (cdash1);
Y ON V (cdash2);
Y ON Q (cdash3);
Y ON XV (cdash4);
Y ON XQ (cdash5);
Y ON VQ (cdash6);
Y ON XVQ (cdash7);

[M] (a0);
M ON X (a1);

! Use model constraint subcommand to test conditional indirect effects
! You need to pick low, medium and high moderator values for V, Q
! for example, of 1 SD below mean, mean, 1 SD above mean

! 2 moderators, 3 values for each, gives 9 combinations
! arbitrary naming convention for conditional indirect and total effects used below:
! MEV_LOQ = medium value of V and low value of Q, etc.

MODEL CONSTRAINT:
NEW(LOW_V MED_V HIGH_V LOW_Q MED_Q HIGH_Q
ILOV_LOQ IMEV_LOQ IHIV_LOQ ILOV_MEQ IMEV_MEQ IHIV_MEQ
ILOV_HIQ IMEV_HIQ IHIV_HIQ
DLOV_LOQ DMEV_LOQ DHIV_LOQ DLOV_MEQ DMEV_MEQ DHIV_MEQ
DLOV_HIQ DMEV_HIQ DHIV_HIQ
TLOV_LOQ TMEV_LOQ THIV_LOQ TLOV_MEQ TMEV_MEQ THIV_MEQ
TLOV_HIQ TMEV_HIQ THIV_HIQ);

LOW_V = #LOWV;   ! replace #LOWV in the code with your chosen low value of V
MED_V = #MEDV;   ! replace #MEDV in the code with your chosen medium value of V
HIGH_V = #HIGHV;   ! replace #HIGHV in the code with your chosen high value of V

LOW_Q = #LOWQ;   ! replace #LOWQ in the code with your chosen low value of Q
MED_Q = #MEDQ;   ! replace #MEDQ in the code with your chosen medium value of Q
HIGH_Q = #HIGHQ;   ! replace #HIGHQ in the code with your chosen high value of Q

! Calc conditional indirect effects for each combination of moderator values

ILOV_LOQ = a1*b1 + a1*b2*LOW_V + a1*b3*LOW_Q + a1*b4*LOW_V*LOW_Q;
IMEV_LOQ = a1*b1 + a1*b2*MED_V + a1*b3*LOW_Q + a1*b4*MED_V*LOW_Q;
IHIV_LOQ = a1*b1 + a1*b2*HIGH_V + a1*b3*LOW_Q + a1*b4*HIGH_V*LOW_Q;

ILOV_MEQ = a1*b1 + a1*b2*LOW_V + a1*b3*MED_Q + a1*b4*LOW_V*MED_Q;
IMEV_MEQ = a1*b1 + a1*b2*MED_V + a1*b3*MED_Q + a1*b4*MED_V*MED_Q;
IHIV_MEQ = a1*b1 + a1*b2*HIGH_V + a1*b3*MED_Q + a1*b4*HIGH_V*MED_Q;

ILOV_HIQ = a1*b1 + a1*b2*LOW_V + a1*b3*HIGH_Q + a1*b4*LOW_V*HIGH_Q;
IMEV_HIQ = a1*b1 + a1*b2*MED_V + a1*b3*HIGH_Q + a1*b4*MED_V*HIGH_Q;
IHIV_HIQ = a1*b1 + a1*b2*HIGH_V + a1*b3*HIGH_Q + a1*b4*HIGH_V*HIGH_Q;

! Calc conditional direct effects for each combination of moderator values

DLOV_LOQ = cdash1 + cdash4*LOW_V + cdash5*LOW_Q + cdash7*LOW_V*LOW_Q;
DMEV_LOQ = cdash1 + cdash4*MED_V + cdash5*LOW_Q + cdash7*MED_V*LOW_Q;
DHIV_LOQ = cdash1 + cdash4*HIGH_V + cdash5*LOW_Q + cdash7*HIGH_V*LOW_Q;

DLOV_MEQ = cdash1 + cdash4*LOW_V + cdash5*MED_Q + cdash7*LOW_V*MED_Q;
DMEV_MEQ = cdash1 + cdash4*MED_V + cdash5*MED_Q + cdash7*MED_V*MED_Q;
DHIV_MEQ = cdash1 + cdash4*HIGH_V + cdash5*MED_Q + cdash7*HIGH_V*MED_Q;

DLOV_HIQ = cdash1 + cdash4*LOW_V + cdash5*HIGH_Q + cdash7*LOW_V*HIGH_Q;
DMEV_HIQ = cdash1 + cdash4*MED_V + cdash5*HIGH_Q + cdash7*MED_V*HIGH_Q;
DHIV_HIQ = cdash1 + cdash4*HIGH_V + cdash5*HIGH_Q + cdash7*HIGH_V*HIGH_Q;

! Calc conditional total effects for each combination of moderator values

TLOV_LOQ = ILOV_LOQ + DLOV_LOQ;
TMEV_LOQ = IMEV_LOQ + DMEV_LOQ;
THIV_LOQ = IHIV_LOQ + DHIV_LOQ;

TLOV_MEQ = ILOV_MEQ + DLOV_MEQ;
TMEV_MEQ = IMEV_MEQ + DMEV_MEQ;
THIV_MEQ = IHIV_MEQ + DHIV_MEQ;

TLOV_HIQ = ILOV_HIQ + DLOV_HIQ;
TMEV_HIQ = IMEV_HIQ + DMEV_HIQ;
THIV_HIQ = IHIV_HIQ + DHIV_HIQ;

! Use loop plot to plot conditional indirect effect of X on Y for each combination of low, med, high moderator values
! Could be edited to show conditional direct or conditional total effects instead
! NOTE - values of 1,5 in LOOP() statement need to be replaced by
! logical min and max limits of predictor X used in analysis

PLOT(PLOV_LOQ PMEV_LOQ PHIV_LOQ PLOV_MEQ PMEV_MEQ PHIV_MEQ
PLOV_HIQ PMEV_HIQ PHIV_HIQ);

LOOP(XVAL,1,5,0.1);

PLOV_LOQ = ILOV_LOQ*XVAL;
PMEV_LOQ = IMEV_LOQ*XVAL;
PHIV_LOQ = IHIV_LOQ*XVAL;

PLOV_MEQ = ILOV_MEQ*XVAL;
PMEV_MEQ = IMEV_MEQ*XVAL;
PHIV_MEQ = IHIV_MEQ*XVAL;

PLOV_HIQ = ILOV_HIQ*XVAL;
PMEV_HIQ = IMEV_HIQ*XVAL;
PHIV_HIQ = IHIV_HIQ*XVAL;

PLOT:
TYPE = plot2;

OUTPUT:
STAND CINT(bcbootstrap);